1 files changed, 87 insertions, 0 deletions
diff --git a/ebuild/layman-1.2.0.ebuild b/ebuild/layman-1.2.0.ebuild
new file mode 100644
index 0000000..fcd24de
--- /dev/null
+++ b/ebuild/layman-1.2.0.ebuild
@@ -0,0 +1,87 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-portage/layman/layman-1.1.1-r1.ebuild,v 1.3 2008/03/20 16:17:29 jokey Exp $
+
+inherit eutils distutils
+
+DESCRIPTION="A python script for retrieving gentoo overlays."
+HOMEPAGE="http://layman.sourceforge.net"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+IUSE="darcs git subversion test"
+
+DEPEND="test? ( dev-util/subversion )"
+RDEPEND="darcs? ( dev-util/darcs )
+		git? ( dev-util/git )
+		subversion? ( dev-util/subversion )"
+
+pkg_setup() {
+	if has_version dev-util/subversion && \
+	(! built_with_use --missing true dev-util/subversion webdav || built_with_use --missing false dev-util/subversion nowebdav); then
+		eerror "You must rebuild your Subversion with support for WebDAV."
+		die "You must rebuild your Subversion with support for WebDAV"
+	fi
+	if ! has_version dev-util/subversion; then
+		ewarn "You do not have dev-util/subversion installed!"
+		ewarn "While layman does not exactly depend on this"
+		ewarn "version control system you should note that"
+		ewarn "most available overlays are offered via"
+		ewarn "dev-util/subversion. If you do not install it"
+		ewarn "you will be unable to use these overlays."
+		ewarn
+	fi
+}
+
+src_install() {
+
+	distutils_src_install
+
+	dodir /etc/layman
+
+	cp etc/* "${D}"/etc/layman/
+
+	doman doc/layman.8
+	dohtml doc/layman.8.html
+
+	keepdir /usr/local/portage/layman
+	touch "${D}"/usr/local/portage/layman/make.conf
+}
+
+src_test() {
+	einfo "Running layman doctests..."
+	echo
+	if ! PYTHONPATH="." ${python} layman/tests/dtest.py; then
+		eerror "DocTests failed - please submit a bug report"
+		die "DocTesting failed!"
+	fi
+}
+
+pkg_postinst() {
+	einfo "You are now ready to add overlays into your system."
+	einfo
+	einfo "layman -L"
+	einfo
+	einfo "will display a list of available overlays."
+	einfo
+	elog  "Select an overlay and add it using"
+	einfo
+	elog  "layman -a overlay-name"
+	einfo
+	elog  "If this is the very first overlay you add with layman,"
+	elog  "you need to append the following statement to your"
+	elog  "/etc/make.conf file:"
+	elog
+	elog  "source /usr/local/portage/layman/make.conf"
+	elog
+	elog  "If you modify the 'storage' parameter in the layman"
+	elog  "configuration file (/etc/layman/layman.cfg) you will"
+	elog  "need to adapt the path given above to the new storage"
+	elog  "directory."
+	einfo
+	ewarn "Please add the 'source' statement to make.conf only AFTER "
+	ewarn "you added your first overlay. Otherwise portage will fail."
+	epause 5
+}