From 426688cd2da30c10ca29da544737a84f6b465e14 Mon Sep 17 00:00:00 2001
From: Sol Jerome <sol.jerome@gmail.com>
Date: Sun, 29 Jan 2012 12:47:28 -0600
Subject: gentoo: Add python-setuptools build dependency

Signed-off-by: Sol Jerome <sol.jerome@gmail.com>
---
 gentoo/bcfg2-1.2.2.ebuild | 62 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 62 insertions(+)
 create mode 100644 gentoo/bcfg2-1.2.2.ebuild

(limited to 'gentoo/bcfg2-1.2.2.ebuild')

diff --git a/gentoo/bcfg2-1.2.2.ebuild b/gentoo/bcfg2-1.2.2.ebuild
new file mode 100644
index 000000000..0ac428bef
--- /dev/null
+++ b/gentoo/bcfg2-1.2.2.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI="3"
+PYTHON_DEPEND="2:2.6"
+SUPPORT_PYTHON_ABIS="1"
+# ssl module required.
+RESTRICT_PYTHON_ABIS="2.4 2.5 3.*"
+
+inherit distutils
+
+DESCRIPTION="configuration management tool"
+HOMEPAGE="http://bcfg2.org"
+
+# handle the "pre" case
+MY_P="${P/_/}"
+SRC_URI="ftp://ftp.mcs.anl.gov/pub/bcfg/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux ~x64-solaris"
+IUSE="server"
+
+DEPEND="dev-python/setuptools"
+RDEPEND="app-portage/gentoolkit
+	server? (
+		dev-python/lxml
+		dev-libs/libgamin[python] )"
+
+PYTHON_MODNAME="Bcfg2"
+
+distutils_src_install_post_hook() {
+	if ! use server; then
+		rm -f "$(distutils_get_intermediate_installation_image)${EPREFIX}/usr/sbin/bcfg2-"*
+	fi
+}
+
+src_install() {
+	distutils_src_install --record=PY_SERVER_LIBS --install-scripts "${EPREFIX}/usr/sbin"
+
+	if ! use server; then
+	    # Remove files only necessary for a server installation
+		rm -rf "${ED}usr/share/bcfg2"
+		rm -rf "${ED}usr/share/man/man8"
+	else
+		newinitd "${FILESDIR}/bcfg2-server.rc" bcfg2-server
+	fi
+
+	insinto /etc
+	doins examples/bcfg2.conf || die "doins failed"
+}
+
+pkg_postinst () {
+	distutils_pkg_postinst
+
+	if use server; then
+		einfo "If this is a new installation, you probably need to run:"
+		einfo "    bcfg2-admin init"
+	fi
+}
-- 
cgit v1.2.3-1-g7c22